【Windows bat】特定のファイルが更新されたことを監視するバッチ

特定のファイルが更新されたかどうかを監視するバッチファイルのサンプルを作りました。

特定のファイルが更新されたことを監視するバッチ

紹介するバッチの動作

本記事で紹介するバッチは、下記のような動作をします。

1. バッチ起動

バッチが起動されると、ファイルが更新されるまで、1秒ごとに”file is not updated…”の文字が出力されます。

2. ファイル更新時

check.txtファイルが更新されると…

“file is updated!!!”が出力されて、バッチが終了します。

バッチのソースコード

バッチファイルのソースコードは下記になります。

@echo off

for %%i in (C:\Cmd\check.txt) do set x=%%~ti

:RECHECK
for %%j in (C:\Cmd\check.txt) do set y=%%~tj

if "%x%"=="%y%" (
    timeout /t 1 > nul
    echo file is not updated...
    GOTO RECHECK
)

echo file is updated!!!

ソースの内容をさらに詳しく知りたい方は、以下の記事も参照してください。

もう少し改良したバッチ

このままだと、下記の場合にバッチがずっと動き続けてしまう問題があります。

この2つの問題を改善するソースコードを紹介します。

改良したバッチの動作

改良したバッチは下記のような動作をします。

1. ファイルが存在しない場合

バッチを起動すると“file is not existed”が表示され、バッチが終了します。

2. ファイルが更新されない場合に中断する

“file-update.bat”バッチを起動します。

別のバッチ“stop-file-update.bat”を起動します。

“file-update.bat is stopped”と表示されて、”file-update.bat”バッチが終了します。

改良したソースコード

上で作成したファイルの更新と、新しくファイルを追加します。

改良した“file-update.bat”ファイルのソースコードはこちら。

@echo off

if not exist C:\Cmd\check.txt (
    echo file is not existed
    exit /B 0
)

for %%i in (C:\Cmd\check.txt) do set x=%%~ti

:RECHECK
for %%j in (C:\Cmd\check.txt) do set y=%%~tj

if "%x%"=="%y%" (

    if exist C:\Cmd\stop-bat.txt (
        echo file-update.bat is stopped
        exit /B 0
    )

    timeout /t 1 > nul
    echo file is not updated...
    GOTO RECHECK
)

echo file is updated!!!

新しく追加する“stop-file-update.bat”ファイルのソースコードはこちらです。

@echo off

copy nul C:\Cmd\stop-bat.txt > nul

timeout /t 5 > nul

del C:\Cmd\stop-bat.txt > nul

ソースの内容をさらに詳しく知りたい方は、以下の記事も参照してください。